wBevel es uno de los controles contenedores básicos de Néfele y tiene su equivalencia en el tag <DIV> de Html.

Su función es encerrar dentro de él otros controles, permitiéndonos así tratarlos de una forma conjunta y crear dentro del documento html secciones que se comportarán de una manera uniforme.

wBevel unido a la potencia del MaterializeCSS y la propiedad Néfele oStyle conforman la base del diseño responsive, que nos permitirá generar páginas web adaptables a las dimensiones del dispositivo en el que se muestran.

WITH OBJECT WBevel():New( :WO )
    :cTitle      := "BANDERA FRANCESA"
    :nStyle      := xc_Row      // el Bevel usará toda la fila
    :cTitleAlign := xc_Center
    :Create()
END

// Bevel contenedor de la bandera
WITH OBJECT WBevel():New( :WO )
    :lShadow         := .T.
    :nStyle          := xc_Row
    :aWidth[ xc_L ]  := 6   // La anchura será de 6/12
    :aOffset[ xc_L ] := 3   // Con un margen izquierdo de 1/3 (para que quede centrado)

    // Barra azul
    WITH OBJECT WBevel():New( :WO )
         :cClrPane       := "blue"  // Color de fondo
         :aWidth[ xc_S ] := 4       // Anchura respecto al bevel que la contine de 4/12 ( o 1/3)
         :oStyle:cHeight := "100%"  // con una altura del 100% del bevel que la contiene
         :Create()
    END

    // Barra Blanca
    WITH OBJECT WBevel():New( :WO )
         :aWidth[ xc_S ] := 4
         :Create()
    END

    // Barra Roja
    WITH OBJECT WBevel():New( :WO )
         :cClrPane       := "red"
         :aWidth[ xc_S ] := 4
         :oStyle:cHeight := "100%"
         :Create()
    END

    :Create()
END WITH